Gecko [ unitednationsplay.com ]

Name	Size	Permission	Date
256term.csh	771 B	-rw-r--r--	2020-11-16 16:20
256term.sh	841 B	-rw-r--r--	2020-11-16 16:20
colorgrep.csh	196 B	-rw-r--r--	2017-03-24 16:39
colorgrep.sh	201 B	-rw-r--r--	2017-03-24 16:39
colorls.csh	1.7 KB	-rw-r--r--	2020-11-16 14:40
colorls.sh	1.57 KB	-rw-r--r--	2020-11-16 14:40
csh.local	80 B	-rw-r--r--	2020-04-01 04:29
flatpak.sh	294 B	-rw-r--r--	2021-11-02 11:52
histtime.sh	40 B	-rw-r--r--	2021-11-01 09:25
lang.csh	1.67 KB	-rw-r--r--	2020-11-16 16:20
lang.sh	2.64 KB	-rw-r--r--	2020-11-16 16:20
less.csh	123 B	-rw-r--r--	2015-07-30 23:47
less.sh	121 B	-rw-r--r--	2015-07-30 23:47
mc.csh	49 B	-rwxr-xr-x	2016-11-05 23:18
mc.sh	153 B	-rwxr-xr-x	2016-11-05 23:18
modules.csh	1.05 KB	-rw-r--r--	2015-11-20 05:43
modules.sh	168 B	-rw-r--r--	2015-06-22 14:13
sh.local	81 B	-rw-r--r--	2020-04-01 04:29
vim.csh	105 B	-rw-r--r--	2020-12-15 16:44
vim.sh	269 B	-rw-r--r--	2020-12-15 16:44
which2.csh	164 B	-rw-r--r--	2014-01-27 20:47
which2.sh	169 B	-rw-r--r--	2014-01-27 20:47

Rename

# skip everything for non-interactive shells
if (! $?prompt) exit

# color-ls initialization
if ( $?USER_LS_COLORS ) then
  if ( "$USER_LS_COLORS" != "" ) then
     #when USER_LS_COLORS defined do not override user
     #specified LS_COLORS and use them
     goto finish
  endif
endif

alias ll 'ls -l'
alias l. 'ls -d .*'
set COLORS=/etc/DIR_COLORS

if ($?TERM) then
  if ( -e "/etc/DIR_COLORS.256color" ) then
    if ( "`/usr/bin/tput colors`" == "256" ) then
       set COLORS=/etc/DIR_COLORS.256color
    endif
  endif
  if ( -e "/etc/DIR_COLORS.$TERM" ) then
     set COLORS="/etc/DIR_COLORS.$TERM"
  endif
endif
if ( -f ~/.dircolors ) set COLORS=~/.dircolors
if ( -f ~/.dir_colors ) set COLORS=~/.dir_colors
if ($?TERM) then
  if ( -f ~/.dircolors."$TERM" ) set COLORS=~/.dircolors."$TERM"
  if ( -f ~/.dir_colors."$TERM" ) set COLORS=~/.dir_colors."$TERM"
endif
set INCLUDE="`/usr/bin/cat "$COLORS" | /usr/bin/grep '^INCLUDE' | /usr/bin/cut -d ' ' -f2-`"

if ( ! -e "$COLORS" ) exit

set _tmp="`/usr/bin/mktemp .colorlsXXX -q --tmpdir=/tmp`"
#if mktemp fails, exit when include was active, otherwise use $COLORS file
if ( "$_tmp" == '' ) then
  if ( "$INCLUDE" == '' ) then
    eval "`/usr/bin/dircolors -c $COLORS`"
  endif
  goto cleanup
endif

if ( "$INCLUDE" != '' ) /usr/bin/cat "$INCLUDE" >> $_tmp
/usr/bin/grep -v '^INCLUDE' "$COLORS" >> $_tmp

eval "`/usr/bin/dircolors -c $_tmp`"

/usr/bin/rm -f $_tmp

if ( "$LS_COLORS" == '' ) exit
cleanup:
set color_none=`/usr/bin/sed -n '/^COLOR.*none/Ip' < $COLORS`
if ( "$color_none" != '' ) then
   unset color_none
   exit
endif
unset color_none
unset _tmp
unset INCLUDE
unset COLORS

finish:
alias ll 'ls -l --color=auto'
alias l. 'ls -d .* --color=auto'
alias ls 'ls --color=auto'