Gecko [ unitednationsplay.com ]

Name	Size	Permission	Date
assert.awk	382 B	-rw-r--r--	2017-06-28 21:52
bits2str.awk	327 B	-rw-r--r--	2017-06-28 21:52
cliff_rand.awk	307 B	-rw-r--r--	2017-06-28 21:52
ctime.awk	233 B	-rw-r--r--	2017-06-28 21:52
ftrans.awk	317 B	-rw-r--r--	2017-06-28 21:52
getopt.awk	2.18 KB	-rw-r--r--	2017-06-28 21:52
gettime.awk	2.43 KB	-rw-r--r--	2017-06-28 21:52
group.awk	1.75 KB	-rw-r--r--	2017-06-28 21:52
join.awk	378 B	-rw-r--r--	2017-06-28 21:52
libintl.awk	238 B	-rw-r--r--	2017-06-28 21:52
noassign.awk	425 B	-rw-r--r--	2017-06-28 21:52
ord.awk	937 B	-rw-r--r--	2017-06-28 21:52
passwd.awk	1.17 KB	-rw-r--r--	2017-06-28 21:52
quicksort.awk	1023 B	-rw-r--r--	2017-06-28 21:52
readable.awk	492 B	-rw-r--r--	2017-06-28 21:52
rewind.awk	404 B	-rw-r--r--	2017-06-28 21:52
round.awk	661 B	-rw-r--r--	2017-06-28 21:52
strtonum.awk	1.43 KB	-rw-r--r--	2017-06-28 21:52
walkarray.awk	214 B	-rw-r--r--	2017-06-28 21:52
zerofile.awk	424 B	-rw-r--r--	2017-06-28 21:52

Rename

# getopt.awk --- Do C library getopt(3) function in awk
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
#
# Initial version: March, 1991
# Revised: May, 1993

# External variables:
#    Optind -- index in ARGV of first nonoption argument
#    Optarg -- string value of argument to current option
#    Opterr -- if nonzero, print our own diagnostic
#    Optopt -- current option letter

# Returns:
#    -1     at end of options
#    "?"    for unrecognized option
#    <c>    a character representing the current option

# Private Data:
#    _opti  -- index in multi-flag option, e.g., -abc
function getopt(argc, argv, options,    thisopt, i)
{
    if (length(options) == 0)    # no options given
        return -1

if (argv[Optind] == "--") {  # all done
        Optind++
        _opti = 0
        return -1
    } else if (argv[Optind] !~ /^-[^:[:space:]]/) {
        _opti = 0
        return -1
    }
    if (_opti == 0)
        _opti = 2
    thisopt = substr(argv[Optind], _opti, 1)
    Optopt = thisopt
    i = index(options, thisopt)
    if (i == 0) {
        if (Opterr)
            printf("%c -- invalid option\n",
                                  thisopt) > "/dev/stderr"
        if (_opti >= length(argv[Optind])) {
            Optind++
            _opti = 0
        } else
            _opti++
        return "?"
    }
    if (substr(options, i + 1, 1) == ":") {
        # get option argument
        if (length(substr(argv[Optind], _opti + 1)) > 0)
            Optarg = substr(argv[Optind], _opti + 1)
        else
            Optarg = argv[++Optind]
        _opti = 0
    } else
        Optarg = ""
    if (_opti == 0 || _opti >= length(argv[Optind])) {
        Optind++
        _opti = 0
    } else
        _opti++
    return thisopt
}
BEGIN {
    Opterr = 1    # default is to diagnose
    Optind = 1    # skip ARGV[0]

# test program
    if (_getopt_test) {
        while ((_go_c = getopt(ARGC, ARGV, "ab:cd")) != -1)
            printf("c = <%c>, optarg = <%s>\n",
                                       _go_c, Optarg)
        printf("non-option arguments:\n")
        for (; Optind < ARGC; Optind++)
            printf("\tARGV[%d] = <%s>\n",
                                    Optind, ARGV[Optind])
    }
}